root/trunk/libffado/tests/SConscript

Revision 1777, 3.0 kB (checked in by arnonym, 11 years ago)

fix #249: Add all needed library-flags to satisfy the pedantic debian tools...

Line 
1 #
2 # Copyright (C) 2007-2008 Arnold Krille
3 # Copyright (C) 2007-2008 Pieter Palmers
4 #
5 # This file is part of FFADO
6 # FFADO = Free Firewire (pro-)audio drivers for linux
7 #
8 # FFADO is based upon FreeBoB.
9 #
10 # This program is free software: you can redistribute it and/or modify
11 # it under the terms of the GNU General Public License as published by
12 # the Free Software Foundation, either version 2 of the License, or
13 # (at your option) version 3 of the License.
14 #
15 # This program is distributed in the hope that it will be useful,
16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 # GNU General Public License for more details.
19 #
20 # You should have received a copy of the GNU General Public License
21 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
22 #
23
24 Import( 'env' )
25
26 env = env.Clone()
27
28 env.MergeFlags( "-I#/ -I#/src -L%ssrc -lffado" % env['build_base'] )
29
30 if not env.GetOption( "clean" ):
31         env.MergeFlags( "-lpthread" )
32         env.MergeFlags( env['LIBIEC61883_FLAGS'] )
33         env.MergeFlags( env['LIBRAW1394_FLAGS'] )
34         if not env['SERIALIZE_USE_EXPAT']:
35                 env.MergeFlags( env['LIBXML26_FLAGS'] )
36         else:
37                 env.PrependUnique( LIBS=["expat"] )
38
39 static_env = env.Clone()
40
41 #
42 # deactivate as they don't seem ported to the new api: test-extplugcmd,
43 # test-mixer, test-volume
44 #
45 apps = {
46         "ffado-test" : "test-ffado.cpp",
47         "test-fw410" : "test-fw410.cpp",
48         #"test-extplugcmd" : "test-extplugcmd.cpp",
49         "test-volume" : "test-volume.cpp",
50         #"test-mixer" : "test-mixer.cpp",
51         "test-enhanced-mixer" : "test-enhanced-mixer.cpp",
52         "test-timestampedbuffer" : "test-timestampedbuffer.cpp",
53         "test-ieee1394service" : "test-ieee1394service.cpp",
54         "test-streamdump" : "test-streamdump.cpp",
55         "test-bufferops" : "test-bufferops.cpp",
56         "test-watchdog" : "test-watchdog.cpp",
57         "test-messagequeue" : "test-messagequeue.cpp",
58         "test-shm" : "test-shm.cpp",
59         "test-ipcringbuffer" : "test-ipcringbuffer.cpp",
60         "test-devicestringparser" : "test-devicestringparser.cpp",
61         "dumpiso_mod" : "dumpiso_mod.cpp",
62         "scan-devreg" : "scan-devreg.cpp"
63 }
64
65 if env['ENABLE_BEBOB']:
66         apps.update( { "test-focusrite" : "test-focusrite.cpp" } )
67 if env['ENABLE_GENERICAVC']:
68         if env.has_key("ALSA_FLAGS") and env["ALSA_FLAGS"]:
69                 env.MergeFlags( env["ALSA_FLAGS"] )
70                 apps.update( { "test-scs" : "test-scs.cpp" } )
71         apps.update( { "test-avccmd" : "test-avccmd.cpp" } )
72 if env['ENABLE_FIREWORKS']:
73         apps.update( { "test-echomixer" : "test-echomixer.cpp" } )
74 if env['ENABLE_DICE']:
75         apps.update( { "test-dice-eap" : "test-dice-eap.cpp" } )
76
77 for app in apps.keys():
78         env.Program( target=app, source = env.Split( apps[app] ) )
79         env.Install( "$bindir", app )
80
81 env.SConscript( dirs=["streaming", "systemtests"], exports="env" )
82
83 # static versions
84 if static_env['BUILD_STATIC_TOOLS']:
85     static_env.Append(LIBS=File('#/src/libffado.a'))
86     for app in apps.keys():
87         static_app = app + "-static"
88         static_env.Program( target=static_app, source = static_env.Split( apps[app] ) )
Note: See TracBrowser for help on using the browser.